Home » Audio » Measurement » Crossover optimization for DI-matched two-way speakers (Polar measurements - Video showing off-axis nulls)
Crossover optimization for DI-matched two-way speakers [message #60363] Thu, 09 July 2009 16:33 Go to next message
Wayne Parham is currently offline  Wayne Parham
Messages: 18670
Registered: January 2001
Illuminati (33rd Degree)

Recently I started a new project, and like all of my loudspeakers, I designed it to provide uniform coverage over a 90°x40° pattern. As most of you know, this means the loudspeaker has to be capable of providing good response throughout its coverage area, which is not an altogether easy task. To test its performance, you have to move the microphone and measure off-axis in several places in addition to straight in front of the speaker.

I have found it isn't too hard to obtain uniform horizontal coverage. That's largely a function of the horn used, which must provide constant directivity along the horizontal plane. The only thing in addition to that are the crossover points, which must be done where the sound sources have matching coverage. In the case of a direct radiating midwoofer and a horn tweeter, the frequency where they match is determined by the size of the woofer and the angular coverage of the tweeter. When using a 90° horn, the woofer matches directivity at the frequency where wavelength is approximately equal to diameter. There is a pretty wide margin here though, I've found that as long as you're within about a third octave, the pattern is still very uniform.

It is harder to get the vertical pattern right. This is because of path length distances between the listener and the woofer and tweeter. Movement along the vertical axis causes the path length differences to change. Once you near 1/2λ, nulls form.

I did a little video that shows these nulls, hoping that would give a clearer picture of what to expect. Some people are already very familiar with this, so it's not news to them. But many people struggle with the concept of vertical nulls, what they are, and how to find them. Hopefully, this video will be helpful, because it shows one of the things I do during development, and it also shows a speaker that I think is a good example as far as vertical coverage is concerned. It has a tall forward lobe that is useful at most any listening distance.
Watch the response curve on the laptop computer, lower right of the video. The S&L measurement system is sending a series of bursts to the speakers, and the microphone captures the signal. When the microphone is positioned anywhere between the vertical nulls, the response curve is basically flat. (Unless I'm talking, of course Smile )

There are dips and peaks at the bottom end of the response curve, but you can disregard them. Those are room modes, a consequence of measuring indoors. You won't see them in an anechoic measurement, response is flat until rolloff begins, which is smooth and gradual, free of those room mode dips.

When I move the microphone to the bottom edge of the speaker, you'll see a notch form in the response curve. That is the lower null. Later, I move the microphone to a position beyond the top edge of the speaker. Watch the response curve as I move the microphone, you'll see it remains flat until I reach the upper null, where a dip again forms.

When I moved the microphone to show the lower null, I moved it just a smidge too far - just past the deepest part of the null. But you can still clearly see the upper and lower nulls, and the smoothness of response in between. Pay attention to the response curve as I move the microphone, you'll see it stays nice and smooth all the way between nulls, over a wide vertical range.

Crossover optimization for DI-matched two-way speakers [message #60370 is a reply to message #60363] Thu, 09 July 2009 21:46 Go to previous messageGo to next message
Wayne Parham is currently offline  Wayne Parham
Messages: 18670
Registered: January 2001
Illuminati (33rd Degree)

This is how I find a crossover that satisfies all the conditions required to simultaneously match the woofer and tweeter sensitivities, provide top-octave equalization for the compression driver's mass rolloff, maintain smooth acoustic phase free from abrupt shifts, match the woofer and tweeter horizontal patterns and also give a nice tall forward lobe with nulls set wide above and below the speaker. That's a lot to do at the same time, but all of these factors are important.

As a prerequisite, see the Speaker Crossover document and familiarize yourself with its concepts. This gives you the basics for crossovers used in a DI-matched two-way loudspeaker, one with a midwoofer and radial horn or waveguide that provides constant horizontal directivity.

For reference, this is the crossover schematic we're using:

http://www.pispeakers.com/threePi_schematic.gif

Disregard the specific values at this point, which change from speaker to speaker.

Top octave compensation is done by R1/R2 and optionally C1 and/or Rs. This π network is what provides conjugate equalization for the compression driver's mass rolloff. It also provides just the right damping of the tweeter circuit to make the first octave or two flat before starting in on the CD equalization 6dB/octave augmentation, around 3kHz.

The Spice model of this crossover is shown below. When modifying filter frequency or slope, pay attention to the values of L1 and C2 (if second-order), also C3 (if third-order) and L5 (if fourth-order) because those are what R1/R2 provide damping for. You will naturally have to play with those values some, for one thing to get the splitter frequency right (for proper horizontal matching) and for another to set the phase, which affects summing and ultimately sets the position of the forward lobe (and vertical nulls). This phase is relative to the woofer phase, so you'll play with the core tweeter high-pass filter, setting it simultaneously with the woofer low-pass to get the right summing and directivity.

As I said, the trick is to juggle the woofer and tweeter circuit to balance all these simultaneous requirements. You can't consider it "done" if all you've looked at is on-axis response. You have to know what the speaker is doing off-axis both in the horizontal and vertical in order to build the best speaker possible. You'll also want to watch the acoustic phase, to make sure there are no abrupt changes. A gradual slope is expected, without a shelf or large peaks or dips.

The good news is you have a baseline, a place to start from, in the circuit description below. You can leverage the experience I have to give yourself a place to start. Here are some guidelines, and some rules of thumb:

1. This is a cut-and-try exercise. Do not think there is a "magic bullet" that can show you what works best. There are too many competing priorities, making this a complex system that doesn't lend itself to a formula or algorithm to tell you what crossover frequencies and slopes to use. It is an empirical exercise that takes manual fitting. Even if there were software "wizard" tools that could find the right values for you, you still would have to work with off-the-shelf standard component values, so some manual resizing would probably be required.

2. There are a few ballpark targets that give a starting point. As I said earlier, the woofer directivity is 90° when the radiating diameter equals one wavelength. Understand that this is radiating diameter, not advertised diameter. So a 12" woofer has something like 10.375" radiating diameter and a 15" woofer is around 13.25". If you're crossing to a 90° horn, your crossover point should be somewhere in the vicinity of the one-wavelength frequency. So for a 12" woofer, that's about 1.3kHz and for a 15" woofer, it's more like 1.0kHz.

In practice, I've found that you have about 30% wiggle room here, so a 12" midwoofer should be low-passed somewhere in the 1.0kHz to 1.6kHz range and a 15" midwoofer should be low-passed between 700Hz and 1.3kHz. I've usually found upward shifts to work better, but not always. The overlap seems to help smooth the directivity blending and (acoustic phase) summing through the transition region.

One thing I've always found though, and that's the best filter was within 30% or so of the one-wavelength rule. Whatever the case, the horizontal directivity should be matched, but this must be balanced with other things too. So try to keep the crossover as close as possible to the one-wavelength goal, while satisfying all the other design goals as well.

3. In the overlap region, the crossover filters aren't quite into their stop bands so their phase shifts are smallest. Also, in the overlap region, horizontal directivies are blended, because off-axis movement in the horizontal plane does not change the phase difference between woofer and tweeter. Woofer directivity may be a little narrower and the tweeter is probably wider, since it is just starting to gain directivity control at the low end. The two balance nicely.

4. It probably goes without saying, but I'll say it anyway. A large midwoofer used to these relatively high frequencies has to be a special breed. It should have low inductance and a well damped cone. The way you'll know if these things are found in your woofer is the response curve. Only a woofer that has a well damped cone can reach the high frequencies without peaks and dips in the response curve. Watch for peaks and dips both on-axis and off-axis. It might be worth a few test measurements to see if your woofer is up to the task before even starting to try and mate the tweeter with a crossover. If the woofer gets weird up high, you'll never be able to get crossover right. You'll think you're dealing with a crossover/summing/nulls issue when in fact you're dealing with a woofer breakup mode. So check your woofer (by itself) and make sure it plays nice in the crossover region.

5. Look at the crossovers I've done. These can be used as starting points for other designs you might do. Note that the components I've used aren't "textbook" values, some not even close.

6. In the Spice model below, there's a list of textbook values for Butterworth low-pass and high-pass filters of various crossovers frequencies and slopes, all assuming an 8Ω load. Notice that the tweeter circuit is loaded by the π pad, and its impedance is higher than 8Ω, so there is some shift there. It's done on purpose to provide specific damping. That's how you can set the level of the first octave independently of the midband and top octave.

Each of the sample filter values is commented out (see the "*" in the first character position on the line). Those can be easily copied-and-pasted into the appropriate filter position in the crossover model when running the WTPro system ICD for loudspeaker development. This will allow you to try various crossover frequencies and slopes easily using the ICD. That's how I do it - It makes the development cycle much faster than calculating a crossover you think will work and then soldering up a physical model and testing with it.

7. It may help to use crossover modeling tools to find slopes and frequencies, but in my experience, there are so many variables it always pays to optimize with measurements. I used to meticulously calculate phase angles and baffle positions to set the position of the forward lobe and vertical nulls. In fact, the first few drafts of the Speaker Crossover document mentioned above, used to have several pages on the subject of finding the acoustic positions and electrical phase to set the position of the forward lobe. I described it as the "window" of constructive summing, with the nulls being set outside, formed by destructive interference from path length differences. I went through a process of calculating electrical phase angles and combining them with estimated acoustic phase and position to determine where the nulls and (major and minor) lobes were. But I later removed those pages because it was too wordy and complicated, and seemed better discussed in another venue. That's what we're doing here now.

One of the problems is the driver itself forms an electro-mechanico-acoustical filter that combines with the crossover's electrical filter, setting the total rolloff as a cumulative result. The compression driver and horn has a pretty complex rolloff slope down low, set by the horn which is beginning to exhibit pipe mode behavior at the low end. The woofer is being pressed hard at its top end, which is nearing inductive and mass rolloff slopes, and it is becoming more directional at the same time. Its cone is also probably starting to flex, so that's making some extra modes too. The bottom line is there are a lot of things happening that make it difficult to estimate acoustic phase and better if you can measure to see what's happening than to try and build a mathematical model. I've done it both ways, and prefer the visibility the measurements give me. It's a tool that makes the work much easier to do, and the results are probably better too.

8. The fully optimized crossover allows the loudspeaker to provide smooth acoustic phase in addition to flat on-axis and off-axis response. There should be no large swings in acoustic phase, which usually show up as corresponding ripples in frequency response. There also must not be a shelf in the acoustic phase, which indicates a full-cycle or multi-cycle shift. Full-cycle shifts are usually not obvious in the on-axis frequency response but may show up in off-axis response. The loudspeaker must provide smooth response on-axis, and vertical off-axis response must also be smooth out to the limits marked by the vertical nulls. Nulls should be approximately equally spaced from the baffle normal, the forward centerline.

Here's a Spice model that can be used with the WTPro ICD:

(Be sure to measure your woofer impedance in the box, and your tweeter impedance on the horn, putting those in the ZMA files associated with the model below.)

* Three Pi Crossover Spice model
*
* Input across nodes 0 & 5, positive to 5
* Tweeter output across 1 & 0, positive to 1
* Woofer output across 7 & 0, positive to 7
*
* component  (+)node  (-)node   value


* input signal
V1 5 0 1.0

* tweeter crossover
C2 5 4 6.8uF
L1 4 0 1.0mH
C3 4 3 20uF

* tweeter compensation
R1 3 1 25 (16 for PSD2002, 25 for DE250)
R2 3 0 16
R5 1 0 16 (Rs swamping resistor)
* C1 3 1 0.47uF

* Eminence PSD2002 tweeter (red to positive)
* Z1 1 0 H290C_PSD2002.zma 0 0

* B&C DE250 tweeter (reverse tweeter leads, black to positive)
Z1 1 0 H290C_DE250.zma 0 0

* woofer crossover
L2 5 7 1.5mH
C4 7 0 10.0uF (10uF for Delta 12LF, 20uF for TD12S)

* Zobel (only used with Delta 12LF woofer)
* R3 7 8 8
* C6 8 0 10.0uF

* TD12S woofer
Z2 7 0 threePi_TD12S.zma 0 0

* Delta 12LF woofer
* Z2 7 0 threePi_Delta12LF.zma 0 0


* First Order


* 1kHz
* woofer
* L2 5 7 1.27mH
* tweeter
* C2 5 3 19.89uF

* 1.1kHz
* woofer
* L2 5 7 1.16mH
* tweeter
* C2 5 3 18.09uF

* 1.2kHz
* woofer
* L2 5 7 1.06mH
* tweeter
* C2 5 3 16.58uF

* 1.3kHz
* woofer
* L2 5 7 0.98mH
* tweeter
* C2 5 3 15.30uF

* 1.4kHz
* woofer
* L2 5 7 0.91mH
* tweeter
* C2 5 3 14.21uF

* 1.5kHz
* woofer
* L2 5 7 0.85mH
* tweeter
* C2 5 3 13.26uF

* 1.6kHz
* woofer
* L2 5 7 0.80mH
* tweeter
* C2 5 3 12.43uF

* 1.7kHz
* woofer
* L2 5 7 0.75mH
* tweeter
* C2 5 3 11.70uF

* 1.8kHz
* woofer
* L2 5 7 0.71mH
* tweeter
* C2 5 3 11.05uF

* 1.9kHz
* woofer
* L2 5 7 0.67mH
* tweeter
* C2 5 3 10.47uF

* 2.0kHz
* woofer
* L2 5 7 0.64mH
* tweeter
* C2 5 3 9.95uF


*Second Order


* 1.0kHz
* woofer
* L2 5 7 1.80mH
* C4 7 0 14.07uF
* tweeter
* C2 5 3 14.07uF
* L1 3 0 1.80mH

* 1.1kHz
* woofer
* L2 5 7 1.64mH
* C4 7 0 12.79uF
* tweeter
* C2 5 3 12.79uF
* L1 3 0 1.64mH

* 1.2kHz
* woofer
* L2 5 7 1.50mH
* C4 7 0 11.72uF
* tweeter
* C2 5 3 11.72uF
* L1 3 0 1.50mH

* 1.3kHz
* woofer
* L2 5 7 1.39mH
* C4 7 0 10.82uF
* tweeter
* C2 5 3 10.82uF
* L1 3 0 1.39mH

* 1.4kHz
* woofer
* L2 5 7 1.29mH
* C4 7 0 10.05uF
* tweeter
* C2 5 3 10.05uF
* L1 3 0 1.29mH

* 1.5kHz
* woofer
* L2 5 7 1.20mH
* C4 7 0 9.38uF
* tweeter
* C2 5 3 9.38uF
* L1 3 0 1.20mH

* 1.6kHz
* woofer
* L2 5 7 1.13mH
* C4 7 0 8.79uF
* tweeter
* C2 5 3 8.79uF
* L1 3 0 1.13mH

* 1.7kHz
* woofer
* L2 5 7 1.06mH
* C4 7 0 8.27uF
* tweeter
* C2 5 3 8.27uF
* L1 3 0 1.06mH

* 1.8kHz
* woofer
* L2 5 7 1.00mH
* C4 7 0 7.82uF
* tweeter
* C2 5 3 7.82uF
* L1 3 0 1.00mH

* 1.9kHz
* woofer
* L2 5 7 0.95mH
* C4 7 0 7.40uF
* tweeter
* C2 5 3 7.40uF
* L1 3 0 0.95mH

* 2.0kHz
* woofer
* L2 5 7 0.90mH
* C4 7 0 7.03uF
* tweeter
* C2 5 3 7.03uF
* L1 3 0 0.90mH


* Third order


* 1.0kHz
* woofer
* L2 5 6 1.91mH
* C4 6 0 26.53uF
* L4 6 7 0.64mH
* tweeter
* C2 5 4 13.26uF
* L1 4 0 0.95mH
* C3 4 3 39.79uF

* 1.1kHz
* woofer
* L2 5 6 1.74mH
* C4 6 0 24.11uF
* L4 6 7 0.58mH
* tweeter
* C2 5 4 12.06uF
* L1 4 0 0.87mH
* C3 4 3 36.17uF

* 1.2kHz
* woofer
* L2 5 6 1.59mH
* C4 6 0 22.10uF
* L4 6 7 0.53mH
* tweeter
* C2 5 4 11.05uF
* L1 4 0 0.80mH
* C3 4 3 33.16uF

* 1.3kHz
* woofer
* L2 5 6 1.47mH
* C4 6 0 20.40uF
* L4 6 7 0.49mH
* tweeter
* C2 5 4 10.20uF
* L1 4 0 0.73mH
* C3 4 3 30.61uF

* 1.4kHz
* woofer
* L2 5 6 1.36mH
* C4 6 0 18.95uF
* L4 6 7 0.45mH
* tweeter
* C2 5 4 9.47uF
* L1 4 0 0.68mH
* C3 4 3 28.42uF

* 1.5kHz
* woofer
* L2 5 6 1.27mH
* C4 6 0 17.68uF
* L4 6 7 0.42mH
* tweeter
* C2 5 4 8.84uF
* L1 4 0 0.64mH
* C3 4 3 26.53uF

* 1.6kHz
* woofer
* L2 5 6 1.19mH
* C4 6 0 16.58uF
* L4 6 7 0.40mH
* tweeter
* C2 5 4 8.29uF
* L1 4 0 0.60mH
* C3 4 3 24.87uF

* 1.7kHz
* woofer
* L2 5 6 1.12mH
* C4 6 0 15.60uF
* L4 6 7 0.37mH
* tweeter
* C2 5 4 7.80uF
* L1 4 0 0.56mH
* C3 4 3 23.41uF

* 1.8kHz
* woofer
* L2 5 6 1.06mH
* C4 6 0 14.74uF
* L4 6 7 0.35mH
* tweeter
* C2 5 4 7.37uF
* L1 4 0 0.53mH
* C3 4 3 22.10uF

* 1.9kHz
* woofer
* L2 5 6 1.01mH
* C4 6 0 13.96uF
* L4 6 7 0.34mH
* tweeter
* C2 5 4 6.98uF
* L1 4 0 0.50mH
* C3 4 3 20.94uF

* 2.0kHz
* woofer
* L2 5 6 0.95mH
* C4 6 0 13.26uF
* L4 6 7 0.32mH
* tweeter
* C2 5 4 6.63uF
* L1 4 0 0.48mH
* C3 4 3 19.89uF


* Fourth Order


* 1.0kHz
* woofer
* L2 5 6 2.35mH
* C4 6 0 25.99uF
* L4 6 7 1.38mH
* C7 7 0 7.61uF
* tweeter
* C2 5 4 10.77uF
* L1 4 0 0.97mH
* C3 4 3 18.38uF
* L5 3 0 3.33mH

* 1.1kHz
* woofer
* L2 5 6 2.14mH
* C4 6 0 23.63uF
* L4 6 7 1.25mH
* C7 7 0 6.92uF
* tweeter
* C2 5 4 9.79uF
* L1 4 0 0.89mH
* C3 4 3 16.71uF
* L5 3 0 3.02mH

* 1.2kHz
* woofer
* L2 5 6 1.96mH
* C4 6 0 21.66uF
* L4 6 7 1.15mH
* C7 7 0 6.34uF
* tweeter
* C2 5 4 8.97uF
* L1 4 0 0.81mH
* C3 4 3 15.32uF
* L5 3 0 2.77mH

* 1.3kHz
* woofer
* L2 5 6 1.81mH
* C4 6 0 19.99uF
* L4 6 7 1.06mH
* C7 7 0 5.86uF
* tweeter
* C2 5 4 8.28uF
* L1 4 0 0.75mH
* C3 4 3 14.14uF
* L5 3 0 2.56mH

* 1.4kHz
* woofer
* L2 5 6 1.68mH
* C4 6 0 18.57uF
* L4 6 7 0.98mH
* C7 7 0 5.44uF
* tweeter
* C2 5 4 7.69uF
* L1 4 0 0.70mH
* C3 4 3 13.13uF
* L5 3 0 2.38mH

* 1.5kHz
* woofer
* L2 5 6 1.57mH
* C4 6 0 17.33uF
* L4 6 7 0.92mH
* C7 7 0 5.08uF
* tweeter
* C2 5 4 7.18uF
* L1 4 0 0.65mH
* C3 4 3 12.25uF
* L5 3 0 2.22mH

* 1.6kHz
* woofer
* L2 5 6 1.47mH
* C4 6 0 16.25uF
* L4 6 7 0.86mH
* C7 7 0 4.76uF
* tweeter
* C2 5 4 6.73uF
* L1 4 0 0.61mH
* C3 4 3 11.49uF
* L5 3 0 2.08mH

* 1.7kHz
* woofer
* L2 5 6 1.38mH
* C4 6 0 15.29uF
* L4 6 7 0.81mH
* C7 7 0 4.48uF
* tweeter
* C2 5 4 6.33uF
* L1 4 0 0.57mH
* C3 4 3 10.81uF
* L5 3 0 1.96mH

* 1.8kHz
* woofer
* L2 5 6 1.31mH
* C4 6 0 14.44uF
* L4 6 7 0.77mH
* C7 7 0 4.23uF
* tweeter
* C2 5 4 5.98uF
* L1 4 0 0.54mH
* C3 4 3 10.21uF
* L5 3 0 1.85mH

* 1.9kHz
* woofer
* L2 5 6 1.24mH
* C4 6 0 13.68uF
* L4 6 7 0.73mH
* C7 7 0 4.01uF
* tweeter
* C2 5 4 5.67uF
* L1 4 0 0.51mH
* C3 4 3 9.67uF
* L5 3 0 1.75mH

* 2.0kHz
* woofer
* L2 5 6 1.18mH
* C4 6 0 13.00uF
* L4 6 7 0.69mH
* C7 7 0 3.81uF
* tweeter
* C2 5 4 5.38uF
* L1 4 0 0.49mH
* C3 4 3 9.19uF
* L5 3 0 1.66mH


.END
Re: Crossover optimization for DI-matched two-way speakers [message #75370 is a reply to message #60370] Mon, 28 January 2013 13:36 Go to previous messageGo to next message
Wayne Parham is currently offline  Wayne Parham
Messages: 18670
Registered: January 2001
Illuminati (33rd Degree)

One thing I've noticed is people that use really short waveguides seem to prefer using small midwoofers. This isn't always the case, of course, but I do think it's a general trend. As an example, think of all the commercially available mini-monitor sized speakers with small midwoofers and short "baffle-dimple" waveguides. Those seem to be a natural fit.

Longer waveguides generally work better for larger midwoofers. This seems to be another natural combination. There are a myriad reasons for this, acoustic loading, resistance/reactance, excursion, etc. but I suspect one of the most fundamental reasons is a long device has an acoustic center that is somewhat further back, and tends to match better with the acoustic center of a larger midwoofer. Another part of this is the smaller woofer needs higher crossover for directivity matching, and shallow waveguides have higher-frequency impedance peaks, so they aren't resistive until relatively high frequency. Both things tend to favor a higher crossover region.

You can adjust these parameters somewhat in the crossover, but you can't go too far with it. One of the conditions that is required of the crossover is to match the phase of the midwoofer with the tweeter, but there are several other simultaneous conditions that must also be met, some with competing priorities. So while the crossover can (and necessarily will) modify phase, and so some tailoring is possible, it shouldn't be done at the expense of something else that is equally important. An example would be to use a low-order high-pass filter in the tweeter circuit which allowed excessive compression driver excursion. Compression drivers have close tolerance between diaphragm and phase plug, and so are particularly sensitive to out-of-band energy.

Whichever way you go, small and short or large and deep, pay attention to the phase between woofer and tweeter when designing the crossover. Whether measuring the forward lobe using the top/bottom process I described in the video clip above, or by doing the reverse connection method to find its center, be careful to find whether the two sound sources are truly on the same cycle, and not shifted by a full cycle or even a multi-cycle shift. You can estimate the acoustic centers and then calculate the phase between drivers through the crossover, but it is a meticulous process. An easier (and more accurate) method is to measure acoustic phase.

The goal is to have acoustic phase within 90° through the audio band. If you see phase shift rapidly in the crossover region, yet the reverse-connection method still shows a null on the baffle normal (straight-forward) axis, then there is a full cycle or a multi-cycle shift. This will usually show up as poor off-axis response, but will not show up in on-axis response.

This is an example of what you are looking for:

http://www.pispeakers.com/Measurements/fourPi_phase.gif

Re: Crossover optimization for DI-matched two-way speakers [message #95895 is a reply to message #75370] Tue, 16 August 2022 08:13 Go to previous messageGo to next message
px4 is currently offline  px4
Messages: 1
Registered: August 2022
Esquire
Can I use that on my TAD 4001 +1601a?
Re: Crossover optimization for DI-matched two-way speakers [message #95896 is a reply to message #95895] Tue, 16 August 2022 11:31 Go to previous message
Wayne Parham is currently offline  Wayne Parham
Messages: 18670
Registered: January 2001
Illuminati (33rd Degree)

Absolutely. This describes a method of setting the crossover to shape the forward lobe.
Previous Topic: Measuring through earbuds
Next Topic: Crossover slopes
Goto Forum:
  


Current Time: Thu Mar 28 17:14:32 CDT 2024

Sponsoring Organizations

DIY Audio Projects
DIY Audio Projects
OddWatt Audio
OddWatt Audio
Pi Speakers
Pi Speakers
Prosound Shootout
Prosound Shootout
Smith & Larson Audio
Smith & Larson Audio
Tubes For Amps
TubesForAmps.com

Lone Star Audiofest